class ElectroServer extends XMLSocket {
	//=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+
	//ElectroServer Class
	//XML Protocol Version 3.2.6
	//ActionScript Version 2.0
	//Author: Jobe Makar, jobe@electrotank.com
	//Company: Electrotank, Inc. http://www.electrotank.com
	//
	//Need help? http://www.electro-server.com/Forum
	//
	//Last edit: 11/11/2004
	//
	//Started: 8/15/03
	//
	//-----Revision History---------
	//	9/18/03		Officially released
	//	9/30/03		Added version detection. If class connects to an older ElectroServer 3 version then an error appears
	//	10/8/03		Fixed createRoom() auto_join bug. Now behaves properly
	//	10/11/03	Fixed chat message bug. A pure number chat message was being converted to a number on reentry
	//	10/20/03	Changed the way variables are parsed in received plugin message
	//	11/5/03		Fixed a case sensitive issue with room variables
	//	11/5/03		Fixed a sendMove/moveReceived issue
	//	11/7/03		Added FloodingFilterEnabled support
	//	11/12/03	In createGameRoom I added support of either description or Description, case insensitive
	//	12/14/03	Added the ability to receive an array of variables in the loggedIn event
	//	12/16/03	Added setModeratorLabel(true|false, "[Mod]") -- If someone is a moderator then their label gets "[Mod]" appended
	//	1/5/04		Fixed default zone name issue
	//	1/19/04		Fixed user variable support issues
	//	2/1/04		Added getLoggedInUserCount(). Requests the total number of users logged into the server in all zones
	//	2/1/04		Added getServerTime(). Returns the number of miliseconds since 1970.
	//	2/12/04		getRoomsInZone('zone name') added. It is there for clients that recieve higher loads of bandwidth. It triggers onRoomsInZoneLoaded
	//	2/23/04		Fixed a WDDX GetRoomsInZone parsing bug
	//	2/26/04		Added a hidden room bug work around to class.
	//	5/6/04		Added event for the response of getLoggedInUserCount. It is es.loggedInUserCountUpdated(num_logged_in)
	//	5/22/04		Added an event to capture the getServerTime method results. onGetServerTime
	//	8/8/04		Fixed a bug that caused the userlist to show incorrect results
	//	8/15/04		Added rawMessageReceived()
	//	8/28/04		Fixed userVariable client-side data saving bug
	//	9/26/2004	Added buddy stuff. es.addBuddy("jobem"), es.removeBuddy("jobem"), es.buddyLoggedIn event, es.buddyLoggedOut event
	//	9/26/2004	Added getUserLocation("jobem") es.userLocationLoaded event is fired when loaded. username, zone, and room are passed in as a string
	//	9/26/2004	Added getUsersInRoom("zone name", "room name"). es.usersInRoomLoaded event is fired. An array of objects with a username property is returned
	//	10/15/2004	Enhanced usersInRoomLoaded event. It now also returns the room and zone names
	//  11/10/2004	Fixed a uservariable update bug.
	//	11/11/2004  Fixed a createGameRoom bug where updatable was always false.
	//	12/15/2004	Added a 4th param to the userListUpdated event, it is a reference to the user object
	//	1/13/2005	Added an optional 3rd parameter to the login(name, pass, variables) method, 'variables'. It is an object that can contain name value pairs, captured by the login event handler on the server
	//	
	//	
	//!!! Download ElectroServer class updates from here: http://www.electrotank.com/ElectroServer/downloads.asp
	//
	//=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+=~=+
	private static var _instance:ElectroServer;
	var MajorVersion:Number = 3;
	var MinorVersion:Number = 2;
	var SubVersion:Number = 0;
	var debug:Boolean = false;
	var showModeratorLabel:Boolean = false;
	var moderatorLabel:String;
	private var ip:String, port:Number, ConnectedToServer:Boolean, pendingRoom:String;
	var inGame:Boolean, joiningRoom:Boolean, pendingZone:String, zone:Object, auto_join:Boolean;
	var myUser:Object, isGameMaster:Boolean, configXML:String, username:String, password:String;
	var buddyList:Array;
	//Events
	var onConnection:Function, loggedIn:Function, zoneChanged:Function, roomListUpdated:Function;
	var roomVariablesUpdated:Function, roomJoined:Function, userListUpdated:Function, messageReceived:Function;
	var moveReceived:Function, usersRenumbered:Function, pluginMessageReceived:Function, zoneUpdated:Function;
	var configurationLoaded:Function, connectionClosed:Function, userVariableUpdated:Function, onRoomsInZoneLoaded:Function;
	var loggedInUserCountUpdated:Function, onGetServerTime:Function, rawMessageReceived:Function;
	var buddyLoggedIn:Function, buddyLoggedOut:Function, userLocationLoaded:Function, usersInRoomLoaded:Function, allZonesLoaded:Function;
	//
	var nodeNameList:Object = {Users:true, Zones:true, UserVariables:true, RoomVariables:true, Rooms:true, Variables:true, BannedUsers:true, Plugins:true, Moderators:true, Words:true, RootWords:true, Templates:true};
	var isConnected:Boolean = false;
	//Cunstructor
	private function ElectroServer() {
		buddyList = new Array();
	}
	private function ValidateVersion(Major:Number, Minor:Number, Sub:Number) {
		var ReturnVal:Boolean = true;
		if (MajorVersion>Major || isNaN(Major)) {
			ReturnVal = false;
		} else if (MinorVersion>Minor && MajorVersion == Major) {
			ReturnVal = false;
		} else if (SubVersion>Sub && MinorVersion == Minor) {
			ReturnVal = false;
		}
		return ReturnVal;
	}
	//
	private function onClose() {
		isConnected = false;
		connectionClosed(true);
	}
	function removeBuddy(name:String) {
		for (var i = 0; i<buddyList.length; ++i) {
			if (buddyList[i].username == name) {
				buddyList.splice(i, 1);
				break;
			}
		}
		var action = "DeleteFriend";
		var parameters = "<FriendName>"+name+"</FriendName>";
		send(action, parameters);
	}
	function getUsersInRoom(zone:String, room:String) {
		var action = "GetUsersInRoom";
		var parameters = "<Zone>"+zone+"</Zone><Room>"+room+"</Room>";
		send(action, parameters);
	}
	function getUserLocation(name:String) {
		var action = "GetUserLocation";
		var parameters = "<UserName>"+name+"</UserName>";
		send(action, parameters);
	}
	function getBuddyList():Array {
		return buddyList;
	}
	function addBuddy(name:String) {
		var buddyExists:Boolean = false;
		for (var i = 0; i<buddyList.length; ++i) {
			if (buddyList[i].username == name) {
				buddyExists = true;
				break;
			}
		}
		if (!buddyExists) {
			var ob = new Object();
			ob.isOnline = false;
			ob.username = name;
			ob.status = "offline";
			ob.label = ob.username+" "+ob.status;
			buddyList.push(ob);
			/////////////////////////////
			var action = "AddFriend";
			var parameters = "<FriendName>"+name+"</FriendName>";
			send(action, parameters);
		}
	}
	function close() {
		super.close();
		connectionClosed(false);
	}
	function getServerTime() {
		var action:String = "GetServerTime";
		var parameters:String = "";
		send(action, parameters);
	}
	function getLoggedInUserCount() {
		var action:String = "GetLoggedInUserCount";
		var parameters:String = "";
		send(action, parameters);
	}
	function setModeratorLabel(val:Boolean, str:String) {
		showModeratorLabel = val;
		moderatorLabel = str;
		if (str == undefined) {
			moderatorLabel = " [Moderator]";
		}
	}
	public static function getInstance():ElectroServer {
		if (_instance == null) {
			_instance = new ElectroServer();
		}
		return _instance;
	}
	function setDebug(val:Boolean) {
		debug = val;
	}
	function getDebug():Boolean {
		return debug;
	}
	function getIP():String {
		return ip;
	}
	function getPort():Number {
		return port;
	}
	function setIP(tempIP:String) {
		ip = tempIP;
	}
	function setPort(tempPort:Number) {
		port = tempPort;
	}
	function deleteRoomVariable(name:String) {
		var action:String = "DeleteRoomVariable";
		var parameters:String = "<RoomVariable ><Name>"+name+"</Name></RoomVariable>";
		send(action, parameters);
	}
	//
	function getRoomsInZone(tmp_zone:String) {
		var action:String = "GetRoomsInZone";
		var parameters:String = "<Zone>"+tmp_zone+"</Zone>";
		send(action, parameters);
	}
	function changeRoomDetail(detail:String, value) {
		var action:String = "ChangeRoomDetails";
		var minorAction:String;
		var field:String;
		detail = detail.toLowerCase();
		var pwordXML:String = "";
		if (detail == "description") {
			minorAction = "ChangeDescription";
			field = "Description";
			value.attributes.isGameRoom = true;
			var wddxOb = new Wddx();
			var descXML = "<![CDATA["+wddxOb.serialize(value)+"]]>";
		} else if (detail == "updatable") {
			minorAction = "ChangeUpdatable";
			field = "Updatable";
			var descXML:String = value;
		} else if (detail == "hidden") {
			minorAction = "ChangeVisibility";
			field = "Hidden";
			var descXML:String = value;
		} else if (detail == "capacity") {
			minorAction = "ChangeCapacity";
			field = "Capacity";
			if (value == undefined || value == 0) {
				value = -1;
			}
			var descXML:String = value;
		} else if (detail == "password") {
			minorAction = "ChangePasswordProtected";
			field = "Password";
			var descXML:String = value;
			var protected:Boolean;
			if (value == undefined) {
				value = "";
			}
			if (value.length>=1) {
				protected = true;
			} else {
				protected = false;
			}
			pwordXML = "<IsProtected>"+protected+"</IsProtected>";
		}
		var parameters:String = "<MinorAction>"+minorAction+"</MinorAction>"+pwordXML+"<"+field+">"+descXML+"</"+field+">";
		send(action, parameters);
	}
	function kick(name:String, reason:String) {
		if (reason == undefined) {
			reason = "";
		}
		var action:String = "ModeratorCommand";
		var parameters:String = "<MinorAction>Kick</MinorAction><UserName>"+name+"</UserName><Reason>"+reason+"</Reason>";
		send(action, parameters);
	}
	function ban(name:String, reason:String, expires) {
		if (reason == undefined) {
			reason = "";
		}
		if (expires == undefined) {
			expires = "-1";
		}
		var action:String = "ModeratorCommand";
		var parameters:String = "<MinorAction>Ban</MinorAction><UserName>"+name+"</UserName><Reason>"+reason+"</Reason><Expires>"+expires+"</Expires>";
		send(action, parameters);
	}
	function createUserVariable(name:String, value:String) {
		var action:String = "UpdateUserVariable";
		var parameters:String = "<MinorAction>Create</MinorAction><Name>"+name+"</Name><Data>"+value+"</Data>";
		send(action, parameters);
	}
	function getAllZones() {
		send("GetAllZones", "");
	}
	function updateUserVariable(name:String, value:String) {
		var action:String = "UpdateUserVariable";
		var parameters:String = "<MinorAction>Update</MinorAction><Name>"+name+"</Name><Data>"+value+"</Data>";
		send(action, parameters);
	}
	function deleteUserVariable(name:String, value:String) {
		var action:String = "UpdateUserVariable";
		var parameters:String = "<MinorAction>Delete</MinorAction><Name>"+name+"</Name>";
		send(action, parameters);
	}
	function createRoomVariable(ob:Object) {
		var name:String = ob.name;
		var data = ob.data;
		var persistent:Boolean = ob.persistent;
		var locked:Boolean = ob.locked;
		if (persistent == undefined) {
			persistent = false;
		}
		if (locked == undefined) {
			locked = false;
		}
		if (zone.myRoom.roomVariables[name] == undefined) {
			var action:String = "CreateRoomVariable";
			var parameters:String = "<RoomVariable Persistent=\""+persistent+"\" Locked=\""+locked+"\" ><Name>"+name+"</Name><Data><![CDATA["+data+"]]></Data></RoomVariable>";
		} else {
			var action:String = "UpdateRoomVariable";
			var parameters:String = "<RoomVariable Locked=\""+locked+"\" ><Name>"+name+"</Name><Data><![CDATA["+data+"]]></Data></RoomVariable>";
		}
		send(action, parameters);
	}
	function getZone() {
		return zone;
	}
	function sendMove(who, ob:Object) {
		var wddxOb:Wddx = new Wddx();
		var moveXML:XML = wddxOb.serialize(ob);
		if (who.toLowerCase() == "all") {
			var action:String = "SendPublicMessage";
			var parameters:String = "<Message><![CDATA["+moveXML+"]]></Message><Variables><Variable><Name>Action</Name><Data>Move</Data></Variable><Variable><Name>MoveType</Name><Data>Public</Data></Variable></Variables>";
		} else {
			var action:String = "SendPrivateMessage";
			var users:Array = who;
			var usersXML:String = "<Users>";
			for (var i = 0; i<users.length; ++i) {
				var user:String = users[i];
				usersXML += "<User>"+user+"</User>";
			}
			usersXML += "</Users>";
			var parameters:String = usersXML+"<Message><![CDATA["+moveXML+"]]></Message><Variables><Variable><Name>Action</Name><Data>Move</Data></Variable><Variable><Name>MoveType</Name><Data>Public</Data></Variable></Variables>";
		}
		send(action, parameters);
	}
	function pluginRequest(plugin:String, method:String, parameters:Object) {
		var action:String = "ExecutePlugin";
		var variableXML:String = "<Variables />";
		if (parameters != undefined) {
			variableXML = "<Variables>";
			for (var i in parameters) {
				variableXML += "<Variable><Name>"+i+"</Name><Value>"+parameters[i]+"</Value></Variable>";
			}
			variableXML += "</Variables>";
		}
		var params:String = "<Plugin>"+plugin+"</Plugin><Method>"+method+"</Method>"+variableXML;
		send(action, params);
	}
	function getRoomVariables() {
		return zone.myRoom.roomVariables;
	}
	function getRoomList() {
		return zone.rooms;
	}
	function getRoom() {
		return zone.myRoom;
	}
	function getUserList() {
		return zone.users;
	}
	function createGameRoom(roomOb:Object) {
		if (roomOb.attributes == undefined) {
			roomOb.attributes = new Object();
		}
		roomOb.attributes.isGameRoom = true;
		if (roomOb.updatable != true) {
			roomOb.updatable = false;
		}
		roomOb.numbered = true;
		createRoom(roomOb);
		inGame = true;
	}
	function joinGame(room:String, password:String, type:String, zone:String) {
		type = type.toLowerCase();
		if (type == "player" || type == undefined) {
			var numbered:Boolean = true;
		} else if (type == "spectator") {
			var numbered:Boolean = false;
		}
		joinRoom(room, password, zone, numbered);
		inGame = true;
	}
	function adminLogin(tempUsername:String, tempPassword:String) {
		myUser.username = tempUsername;
		if (tempPassword == undefined) {
			tempPassword = "";
		}
		myUser.password = tempPassword;
		username = myUser.username;
		password = myUser.password;
		var action:String = "AdminLogin";
		var parameters:String = "<Name>"+myUser.username+"</Name><Password>"+myUser.password+"</Password>";
		send(action, parameters);
	}
	function loadConfiguration() {
		var action:String = "LoadConfiguration";
		var parameters:String = "";
		send(action, parameters);
	}
	function parseConfig(config:String) {
		XML.prototype.ignoreWhite = true;
		var temp:XML = new XML(config);
		var params:Object = new Object();
		parseParameters(temp.firstChild.childNodes, params);
		configurationLoaded(params);
	}
	function sendMessage(type:String, message:String, users:Array, variables:Object) {
		var type:String = type.toLowerCase();
		if (type == "public" || type == "all") {
			//'users' is actually the variables for public messages
			sendPublicMessage(message, users);
		} else if (type == "private") {
			sendPrivateMessage(message, users, variables);
		}
	}
	function joinRoom(room:String, password:String, zoneName:String, numbered:Boolean) {
		var action = "JoinRoom";
		if (numbered == undefined) {
			numbered = true;
		}
		if (password == undefined) {
			password = "";
		}
		if (zoneName == undefined) {
			zoneName = getZone().name;
			if (zoneName == undefined) {
				zoneName = "Chat Area";
			}
		}
		pendingRoom = room;
		inGame = false;
		var parameters:String = "<Zone><Name>"+zoneName+"</Name><Room><Name>"+room+"</Name><Password>"+password+"</Password><Numbered>"+numbered+"</Numbered></Room></Zone>";
		send(action, parameters);
	}
	function createRoom(roomOb:Object, auto:Boolean) {
		//roomOb properties: zone, roomName, hidden, numbered, UserVariablesEnabled, Description
		//Password, Capacity, roomVariables
		if (auto == undefined || auto == "true") {
			auto = true;
		} else {
			auto = false;
		}
		auto_join = auto;
		var action:String = "CreateRoom";
		var password:String = roomOb.password;
		var UserVariablesEnabled:Boolean = roomOb.userVariablesEnabled;
		var hidden:Boolean = roomOb.hidden;
		var zoneName:String = roomOb.zone;
		var roomName:String = roomOb.roomName;
		var numbered:Boolean = roomOb.numbered;
		var capacity:Number = roomOb.capacity;
		var description:String = roomOb.description;
		var roomVariables:Array = roomOb.roomVariables;
		var updatable:Boolean = roomOb.updatable;
		var plugins:Array = roomOb.plugins;
		var FloodingFilterEnabled:Boolean = roomOb.FloodingFilterEnabled;
		var descOb:Object = new Object();
		if (description == undefined) {
			description = roomOb.Description;
			if (description == undefined) {
				description = "";
			}
		}
		if (FloodingFilterEnabled == undefined) {
			FloodingFilterEnabled = false;
		}
		descOb.description = description;
		if (roomOb.attributes != undefined) {
			descOb.attributes = roomOb.attributes;
		}
		var wddxOb:Wddx = new Wddx();
		var descXML:XML = wddxOb.serialize(descOb);
		if (zoneName == undefined) {
			zoneName = getZone().name;
			if (zoneName == undefined) {
				zoneName = "Chat Area";
			}
		}
		if (updatable == undefined) {
			updatable = true;
		}
		if (hidden == undefined) {
			hidden = false;
		}
		if (capacity == undefined) {
			capacity = -1;
		}
		if (numbered == undefined) {
			numbered = false;
		}
		if (password == undefined) {
			password = "";
		}
		if (UserVariablesEnabled == undefined) {
			UserVariablesEnabled = false;
		}
		if (roomVariables == undefined) {
			var roomVariableXML:String = "<RoomVariables/>";
		} else {
			var roomVariableXML:String = "<RoomVariables>";
			for (var i = 0; i<roomVariables.length; ++i) {
				var ob:Object = roomVariables[i];
				var persistent:Boolean = ob.persistent;
				var locked:Boolean = ob.locked;
				var name:String = ob.name;
				var data = ob.data;
				if (persistent == undefined) {
					persistent = false;
				}
				if (locked == undefined) {
					locked = false;
				}
				var str:String = "<RoomVariable Persistent=\""+persistent+"\" Locked=\""+locked+"\">";
				str += "<Name>"+name+"</Name>";
				str += "<Data><![CDATA["+data+"]]></Data>";
				str += "</RoomVariable>";
				roomVariableXML += str;
			}
			roomVariableXML += "</RoomVariables>";
		}
		if (plugins == undefined) {
			var pluginXML:String = "<Plugins />";
		} else {
			var pluginXML:String = "<Plugins>";
			for (var i = 0; i<plugins.length; ++i) {
				var plugin:Object = plugins[i];
				var name:String = plugin.name;
				var pluginVariables:Object = plugin.variables;
				if (pluginVariables == undefined) {
					var pluginVariablesXML:String = "<Variables />";
				} else {
					var pluginVariablesXML:String = "<Variables>";
					for (var j in pluginVariables) {
						var pluginVarValue = pluginVariables[j];
						pluginVariablesXML += "<Variable><Name>"+j+"</Name><Value>"+pluginVarValue+"</Value></Variable>";
					}
					pluginVariablesXML += "</Variables>";
				}
				pluginXML += "<Plugin><Name>"+name+"</Name>"+pluginVariablesXML+"</Plugin>";
			}
			pluginXML += "</Plugins>";
		}
		var parameters:String = "<Zone><Name>"+zoneName+"</Name><Room Updatable=\""+updatable+"\" Hidden=\""+hidden+"\" FloodingFilterEnabled=\""+FloodingFilterEnabled+"\" Numbered=\""+numbered+"\" UserVariablesEnabled=\""+UserVariablesEnabled+"\"><Name>"+roomName+"</Name><Password>"+password+"</Password><Description><![CDATA["+descXML+"]]></Description><Capacity>"+capacity+"</Capacity>"+roomVariableXML+pluginXML+"</Room></Zone>";
		joiningRoom = true;
		pendingRoom = roomName;
		pendingZone = zoneName;
		inGame = false;
		send(action, parameters);
	}
	function sendPublicMessage(message:String, variables:Object) {
		var action:String = "SendPublicMessage";
		//var parameters = "<Message><![CDATA["+message+"]]></Message><Variables><Variable><Name>Test Var</Name><Data>Yaya</Data></Variables>";
		var variableXML:String = "";
		for (var i in variables) {
			var value:String = variables[i].toString();
			variableXML += "<Variable><Name>"+i+"</Name><Data><![CDATA["+value+"]]></Data></Variable>";
		}
		if (variableXML != "") {
			variableXML = "<Variables>"+variableXML+"</Variables>";
		} else {
			variableXML = "<Variables />";
		}
		var parameters:String = "<Message><![CDATA["+message+"]]></Message>"+variableXML;
		send(action, parameters);
	}
	function sendPrivateMessage(message:String, users:Array, variables:Object) {
		var action:String = "SendPrivateMessage";
		var usersXML:String = "<Users>";
		for (var i = 0; i<users.length; ++i) {
			var user:Object = users[i];
			usersXML += "<User>"+user+"</User>";
		}
		usersXML += "</Users>";
		var variableXML:String = "";
		for (var i in variables) {
			var value = variables[i];
			variableXML += "<Variable><Name>"+i+"</Name><Data><![CDATA["+value+"]]></Data></Variable>";
		}
		if (variableXML != "") {
			variableXML = "<Variables>"+variableXML+"</Variables>";
		} else {
			variableXML = "<Variables />";
		}
		var parameters:String = usersXML+"<Message>"+message+"</Message>"+variableXML;
		send(action, parameters);
	}
	function connectionResponse(success:Boolean) {
		//This occurs when the basic connection is established with the socket-server
		ConnectedToServer = true;
		if (!ConnectedToServer) {
			//Could not find server or server is turned off
			connectionEstablished(false, "Could not establish a server connection");
		}
	}
	function connectionEstablished(success:Boolean, reason:String) {
		//Sucessfully connection to ElectroServer is a two stage process.
		//First you must establish a connection. Then ElectroServer must tell you that it is ok.
		if (success && ConnectedToServer) {
			//connected successfully
			isConnected = true;
			onConnection(true);
		} else {
			//Did not connect successfully
			onConnection(false, reason);
		}
	}
	function XMLReceived(info:XML) {
		var validXML:Boolean = info.toString().substr(0, 1) == "<";
		if (validXML) {
			parseXML(info);
		} else {
			rawMessageReceived(info.toString());
		}
	}
	function parseXML(data:XML) {
		//hidden
		//Every packet of XML that is pushed in from the server hits this method forist
		if (getDebug()) {
			trace("-----incomming----");
			trace(data);
		}
		var info:Array = data.firstChild.childNodes;
		//Every XML packet has an action
		var action:String = info[0].firstChild.nodeValue;
		//Parse the parameters into easy-to-use data objects
		var parameters:Array = info[1].childNodes;
		var params:Object = new Object();
		parseParameters(parameters, params);
		//Apply the action
		applyAction(action, params);
	}
	function isArrayNodeName(nodeName:String):Boolean {
		//hidden
		//The parseParameters function treats all nodes the same unless they are in
		// the 'nodeNameList', in which case they are converted to arrays
		//This function returns true|false depending on if the nodeName is in the list
		if (nodeNameList[nodeName]) {
			return true;
		} else {
			return false;
		}
	}
	function terminateHere(xmls:XML):Boolean {
		//hidden
		//This is used by parseParameters to determine how deep the XML goes
		return xmls.childNodes[0].hasChildNodes() ? false : true;
	}
	function send(action:String, parameters:String) {
		//hidden
		var message:String = "<XmlDoc><Action>"+action+"</Action><Parameters>"+parameters+"</Parameters></XmlDoc>";
		if (getDebug()) {
			trace("---out going----");
			trace(message);
		}
		super.send(message);
	}
	function parseParameters(info:Array, parentOb:Object) {
		//hidden
		//This is a generic recursive method which walks the parameters node of the message
		//it parses the XML into generic data objects
		//====
		// example:
		// <Parameters><Results>Success</Results></Parameters>
		// parses to  parameters.results which is an object, the value of 'Results' is:
		// parameters.Results.value
		for (var i = 0; i<info.length; ++i) {
			var xmls:XML = info[i];
			var terminate:Boolean = terminateHere(xmls);
			var nodeName:String = xmls.nodeName;
			if (parentOb instanceof Array) {
				var ob:Object = new Object();
				parentOb.push(ob);
				var ob:Object = parentOb[parentOb.length-1];
			} else {
				parentOb[nodeName] = new Object();
				var ob:Object = parentOb[nodeName];
			}
			for (var j in xmls.attributes) {
				if (ob.attributes == undefined) {
					ob.attributes = new Object();
				}
				var value:String = xmls.attributes[j];
				if (!isNaN(Number(value))) {
					var value:Number = Number(value);
				}
				if (value.toLowerCase() == "true") {
					var value:Boolean = true;
				} else if (value.toLowerCase() == "false") {
					var value:Boolean = false;
				}
				ob.attributes[j] = value;
			}
			if (isArrayNodeName(nodeName)) {
				ob[nodeName] = new Array();
				var ob:Object = ob[nodeName];
			}
			if (terminate) {
				// No further sub-nodes
				var nodeValue:String = xmls.firstChild.nodeValue;
				if (!isNaN(Number(nodeValue)) && nodeValue != undefined && xmls.nodeName != "Message") {
					var nodeValue:Number = Number(nodeValue);
				}
				ob.value = nodeValue;
			} else {
				// There are sub-nodes that need parsing
				var nodeName:String = xmls.nodeName;
				var children:Array = xmls.childNodes;
				parseParameters(children, ob);
			}
		}
	}
	function login(tempUsername:String, tempPassword:String, variables:Object) {
		username = tempUsername;
		if (username == undefined || username == null) {
			username = "";
		}
		if (tempPassword == undefined) {
			password = "";
		} else {
			password = tempPassword;
		}
		//user.password = password;
		//username = user.username;
		//password = user.password;
		var action:String = "Login";
		var parameters:String = "<Name>"+username+"</Name><Password>"+password+"</Password>";
		if (variables != undefined) {
			parameters += "<EventHandlerVariables>";
			for (var i in variables) {
				parameters += "<EventHandlerVariable>";
				parameters += "<Name>"+i+"</Name>";
				parameters += "<Data>"+variables[i]+"</Data>";
				parameters += "</EventHandlerVariable>";
			}
			parameters += "</EventHandlerVariables>";
		}
		send(action, parameters);
	}
	function connect() {
		//Override the XMLSocket connect method
		onConnect = connectionResponse;
		onXML = XMLReceived;
		super.connect(getIP(), getPort());
	}
	function getUser() {
		return myUser;
	}
	private function applyAction(action:String, params:Object) {
		if (action == "ConnectionResponse") {
			//This is a willful response from the server
			var Major:Number = Number(params.Version.attributes.Major);
			var Minor:Number = Number(params.Version.attributes.Minor);
			var Sub:Number = Number(params.Version.attributes.Sub);
			if (params.Result.value == "Accepted" && ValidateVersion(Major, Minor, Sub)) {
				connectionEstablished(true);
			} else {
				//did not connect properly
				if (params.Result.value == "Accepted" && !ValidateVersion(Major, Minor, Sub)) {
					var error = "ElectroServer 3 version is too old. Please install latest.";
					trace("=====================================================");
					trace("===============Error Error Error=====================");
					trace("This class file is newer than the version of ElectroServer 3 that you are using.");
					trace("AS 2.0 Class version: "+MajorVersion+"."+MinorVersion+"."+SubVersion);
					trace("ElectroServer version: "+Major+"."+Minor+"."+Sub);
					trace("If it says NaN above, then you definately need to update.");
					trace("Visit http://www.electrotank.com/ElectroServer/");
					trace("=====================================================");
					trace("=====================================================");
				} else {
					var error = params.Reason.value;
				}
				connectionEstablished(false, error);
			}
		} else if (action == "LoginResponse") {
			if (params.Result.value.toLowerCase() == "accepted") {
				//var variables_array:Array = params.Variables.Variables;
				var variables:Array = params.Variables.Variables;
				var var_ob:Object = new Object();
				for (var j=0;j<variables.length;++j) {
					var ob = variables[j];
					var name = ob.Name.value;
					var value = ob.Data.value;
					var_ob[name] = value;
				}
				loggedIn(true, undefined, var_ob);
			} else {
				var error = params.Reason.value;
				loggedIn(false, error);
			}
		} else if (action == "GetAllZones") {
			var arr = params.Zones.Zones;
			var zones = new Array();
			for (var i=0;i<arr.length;++i) {
				var ob = arr[i]
				zones.push(ob.value)
			}
			allZonesLoaded(zones)
		} else if (action == "GetUserLocation") {
			var name = params.User.value
			var tmp_zone = params.Zone.value;
			var room = params.Room.value;
			userLocationLoaded(name, tmp_zone, room);
		} else if (action == "GetUsersInRoom") {
			var arr = params.Users.Users;
			var returnArr = new Array();
			for (var i=0;i<arr.length;++i) {
				var ob = new Object();
				ob.username = arr[i].value
				returnArr.push(ob);
			}
			usersInRoomLoaded(returnArr, params.Room.value, params.Zone.value);
		} else if (action == "FriendLoggedOut") {
			var name = params.FriendName.value;
			for (var i=0;i<buddyList.length;++i) {
				var ob = buddyList[i];
				if (ob.username == name) {
					ob.online = false;
					ob.status = "offline";
					ob.label = ob.username +" "+ob.status;
					break;
				}
			}
			buddyLoggedOut(name);
		} else if (action == "FriendLoggedIn") {
			var name = params.FriendName.value;
			for (var i = 0; i<buddyList.length; ++i) {
				var ob = buddyList[i];
				if (ob.username == name) {
					ob.online = true;
					ob.status = "online";
					ob.label = ob.username+" "+ob.status;
					break;
				}
			}
			buddyLoggedIn(name);
		} else if (action == "CreateRoom") {
			if (params.Result.value == "Failure") {
				var error = params.Reason.value;
				if (error.indexOf("already exists")>-1 && auto_join) {
					joinRoom(pendingRoom, "", pendingZone);
				}
			} else {
				//Success, do nothing
			}
		} else if (action == "LoadConfiguration") {
			//This is for admin
			var num_packets:String = params.NumberOfPackets.value;
			var num:String = params.PacketNumber.value;
			var packetData:String = params.PacketData.value;
			if (num == "1") {
				configXML = packetData;
			} else {
				configXML += packetData;
			}
			if (num == num_packets) {
				parseConfig(configXML);
			}
		} else if (action == "UpdateUserVariable") {
			var users = zone.users;
			var ob = params.UserVariable;
			var tmp_user = ob.User.value;
			var value = ob.Data.value;
			var name = ob.Name.value;
			for (var i = 0; i<users.length; ++i) {
				var tmp = users[i].Name.value;
				if (tmp_user == tmp) {
					var user = users[i];
					var type = typeof user.userVariables[name];
					if (type.toString() == "undefined") {
						if (typeof user.userVariables.toString() == "undefined") {
							user.userVariables = new Object();
						}
						user.userVariables[name] = value;
						userVariableUpdated(user, "created", name);
					} else {
						user.userVariables[name] = value;
						userVariableUpdated(user, "updated", name);
					}
					break;
				}
			}
		} else if (action == "JoinRoom") {
			if (params.Result.value == "Success") {
				//joined the room successfully
				var roomName:String = pendingRoom;
				var roomList:Array = zone.rooms;
				for (var i = 0; i<roomList.length; ++i) {
					var roomOb:Object = roomList[i];
					if (roomOb.Name.value == roomName) {
						zone.myRoom = roomOb;
						var rv = params.RoomVariables.RoomVariables;
						zone.myRoom.roomVariables = new Object();
						for (var j = 0; j<rv.length; ++j) {
							var name = rv[j].Name.value;
							var value = rv[j].Data.value;
							zone.myRoom.roomVariables[name] = value;
						}
						roomVariablesUpdated("all", zone.myRoom.roomVariables);
						break;
					}
				}
				roomJoined({success:true}, zone.myRoom);
				delete pendingRoom;
				joiningRoom = false;
				//deal with userlist
				zone.users = params.Users.Users;
				for (var i = 0; i<zone.users.length; ++i) {
					var user:Object = zone.users[i];
					user.label = user.Name.value;
					if (showModeratorLabel && user.attributes.Moderator) {
						user.label += moderatorLabel;
					}
					user.data = user;
					var uv = user.UserVariables.UserVariables;
					user.userVariables = new Object();
					for (var k = 0; k<uv.length; ++k) {
						var u = uv[k];
						var user_var_name = u.Name.value;
						var user_var_val = u.Data.value;
						user.userVariables[user_var_name] = user_var_val;
					}
					if (user.Name.value == username) {
						myUser = user;
						if (user.AssignedNumber.value == 0) {
							user.isGameMaster = true;
						}
					}
				}
				userListUpdated(zone.users, "all");
			} else {
				//Failed to join the room
				var error = params.Reason.value;
				roomJoined({success:false, error:error});
			}
		} else if (action == "RenumberUsers") {
			var users = zone.users;
			for (var i = 0; i<params.Users.Users.length; ++i) {
				var uname:String = params.Users.Users[i].Name.value;
				for (var j = 0; j<users.length; ++j) {
					if (uname == users[j].Name.value) {
						users[j].AssignedNumber.value = params.Users.Users[i].AssignedNumber.value;
						users[j].isGameMaster = false;
					}
				}
				if (getUser().AssignedNumber.value == 0) {
					getUser().isGameMaster = true;
				}
			}
			if (getUser().AssignedNumber.value == 0) {
				isGameMaster = true;
			} else {
				isGameMaster = false;
			}
			usersRenumbered(users);
		} else if (action == "SendPrivateMessage") {
			var message = params.Message.value;
			var from = params.User.value;
			var variables = new Object();
			for (var i = 0; i<params.Variables.Variables.length; ++i) {
				var name = params.Variables.Variables[i].Name.value;
				var value = params.Variables.Variables[i].Data.value;
				variables[name] = value;
			}
			if (variables.Action.toLowerCase() == "move") {
				var what:String = message;
				var foo:Wddx = new Wddx();
				var ob:Object = foo.deserialize(what);
				moveReceived("private", ob, from);
			} else {
				messageReceived("private", message, from, variables);
			}
		} else if (action == "SendPublicMessage") {
			var message:String = params.Message.value;
			var from:String = params.User.value;
			var variables:Object = new Object();
			for (var i = 0; i<params.Variables.Variables.length; ++i) {
				var name:String = params.Variables.Variables[i].Name.value;
				var value = params.Variables.Variables[i].Data.value;
				variables[name] = value;
			}
			if (variables.Action.toLowerCase() == "move") {
				var what:String = message;
				var foo:Wddx = new Wddx();
				var ob:Object = foo.deserialize(what);
				moveReceived("public", ob, from);
			} else {
				messageReceived("public", message, from, variables);
			}
		} else if (action == "GetRoomsInZone") {
			var tmp_rooms = params.Zone.Rooms.Rooms;
			var show_nums = true;
			var roomsToReturn = new Array();
			for (var i = 0; i<tmp_rooms.length; ++i) {
				var room_name = tmp_rooms[i].Name.value;
				var label:String = "";
				if (show_nums) {
					label = room_name+" ("+tmp_rooms[i].attributes.Users+")";
				} else {
					label = room_name;
				}
				tmp_rooms[i].label = label;
				tmp_rooms[i].iconAlignment = "right";
				var WDDXxml:String = tmp_rooms[i].Description.value;
				if (WDDXxml.length>2) {
					var foo:Wddx = new Wddx();
					var ob:Object = foo.deserialize(WDDXxml);
				} else {
					var ob:Object = new Object();
				}
				tmp_rooms[i].Description = ob;
				//var room:Object = zone.rooms[i];
				//room.data = room;
			}
			onRoomsInZoneLoaded(tmp_rooms, params.Zone.Name.value);
		} else if (action == "RoomList") {
			var myOldRoom = getRoom();
			var oldUsers = getUserList();
			zone = new Object();
			zone.numUsers = Number(params.Zone.attributes.Users);
			zone.name = params.Zone.Name.value;
			zone.rooms = params.Zone.Rooms.Rooms;
			for (var i = 0; i<zone.rooms.length; ++i) {
				var WDDXxml:String = zone.rooms[i].Description.value;
				if (WDDXxml.length>2) {
					var foo:Wddx = new Wddx();
					var ob:Object = foo.deserialize(WDDXxml);
				} else {
					var ob:Object = new Object();
				}
				zone.rooms[i].Description = ob;
				var room:Object = zone.rooms[i];
				room.label = room.Name.value;
				room.data = room;
				if (myOldRoom.Name.value == room.Name.value) {
					zone.rooms[i] = myOldRoom;
					zone.myRoom = myOldRoom;
					zone.users = oldUsers;
				}
			}
			zoneChanged(zone.name);
			roomListUpdated(zone.rooms, "all");
		} else if (action == "UpdateUserList") {
			var minorAction:String = params.MinorAction.value;
			if (minorAction == "UserJoined") {
				var users = zone.users;
				var user = params.User;
				//
				var user_name = user.Name.value;
				var uv = user.UserVariables.UserVariables;
				user.userVariables = new Object();
				for (var k = 0; k<uv.length; ++k) {
					var u = uv[k];
					var user_var_name = u.Name.value;
					var user_var_val = u.Data.value;
					user.userVariables[user_var_name] = user_var_val;
				}

				//
				user.label = user.Name.value;
				if (showModeratorLabel && user.attributes.Moderator) {
					user.label += moderatorLabel;
				}
				user.data = user;
				users.push(user);
				userListUpdated(zone.users, "userjoined", user.Name.value, user);
			} else if (minorAction == "UserLeft") {
				var users = zone.users;
				var user = params.User;
				var uname = user.Name.value;
				for (var i = 0; i<users.length; ++i) {
					var name = users[i].Name.value;
					if (uname == name) {
						users.splice(i, 1);
						break;
					}
				}
				userListUpdated(zone.users, "userleft", user.Name.value);
			}
		} else if (action == "SendPluginMessage") {
			var plugin:String = params.User.value;
			var pluginAction:String = params.Message.value;
			var variables:Array = params.Variables.Variables;
			var ob:Object = new Object();
			for (var i = 0; i<variables.length; ++i) {
				var name:String = variables[i].Name.value;
				var value = variables[i].Value.value;
				ob[name] = value;
			}
			pluginMessageReceived(plugin, pluginAction, ob);
		} else if (action == "UpdateRoomVariable") {
			var minorAction:String = params.MinorAction.value;
			if (minorAction == "Create") {
				var name:String = params.RoomVariable.Name.value;
				var value = params.RoomVariable.Data.value;
				zone.myRoom.roomVariables[name] = value;
				roomVariablesUpdated("created", zone.myRoom.roomVariables, name);
			} else if (minorAction == "Update") {
				var name:String = params.RoomVariable.Name.value;
				var value = params.RoomVariable.Data.value;
				zone.myRoom.roomVariables[name] = value;
				roomVariablesUpdated("updated", zone.myRoom.roomVariables, name);
			} else if (minorAction == "Delete") {
				var name:String = params.RoomVariable.Name.value;
				delete zone.myRoom.roomVariables[name];
				roomVariablesUpdated("deleted", zone.myRoom.roomVariables, name);
			}
		} else if (action == "GetLoggedInUserCount") {
			var num = Number(params.LoggedInUsers.value);
			loggedInUserCountUpdated(num);
		} else if (action == "GetServerTime") {
			var num = Number(params.ServerTime.value);
			onGetServerTime(num);
		} else if (action == "UpdateRoomList") {
			var minorAction:String = params.MinorAction.value;
			zone.numUsers = Number(params.Zone.attributes.Users);
			zoneUpdated(zone.numUsers);
			var newRoomOb:Object = params.Zone.Rooms.Rooms[0];
			if (minorAction == "ChangeRoomDetails") {
				//Room that already exists was changed
				for (var j = 0; j<zone.rooms.length; ++j) {
					var roomOb:Object = zone.rooms[j];
					if (roomOb.Name.value == newRoomOb.Name.value) {
						roomOb.label = roomOb.Name.value;
						roomOb.data = roomOb;
						for (var i in newRoomOb) {
							roomOb[i] = newRoomOb[i];
						}
						var WDDXxml:String = newRoomOb.Description.value;
						if (WDDXxml.length>2) {
							var foo:Wddx = new Wddx();
							var ob:Object = foo.deserialize(WDDXxml);
						} else {
							var ob:Object = new Object();
						}
						roomOb.Description = ob;
						break;
					}
				}
				roomListUpdated(zone.rooms, "roomupdated", roomOb);
			} else if (minorAction == "CreateRoom") {
				//Add a new room to the room list
				var roomOb:Object = newRoomOb;
				roomOb.label = roomOb.Name.value;
				roomOb.data = roomOb;
				var WDDXxml:XML = roomOb.Description.value;
				var foo:Wddx = new Wddx();
				var ob:Object = foo.deserialize(WDDXxml);
				roomOb.Description = ob;
				zone.rooms.push(roomOb);
				roomListUpdated(zone.rooms, "roomcreated", roomOb);
			} else if (minorAction == "DeleteRoom") {
				//Room that already exists was deleted
				for (var j = 0; j<zone.rooms.length; ++j) {
					var roomOb:Object = zone.rooms[j];
					if (roomOb.Name.value == newRoomOb.Name.value) {
						var deleteIt = true;
						var name = newRoomOb.Name.value;
						if (name == getRoom().Name.value && !joiningRoom) {
							deleteIt = false;
						}
						if (deleteIt) {
							zone.rooms.splice(j, 1);
						}
						break;
					}
				}
				roomListUpdated(zone.rooms, "RoomDeleted", name);
			}
		}
	}
}